***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Oct 25, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZX584C3 A K 
.param
+vc0 = 2.446e-9 	 vc1 = 4.846e-8		 vc2 = 1.500e0		 vc3 = 8.377e-7		 vc4 = 8.011e0
+tc1 = 5.651e-3		 tc2 = 4.921e-3		 tc3 = 4.551e-3		 tc4 = 1.021e-3
.func irpwr(v) {(vc0+vc1*v^vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v^vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1 
***** dc model parameter *****
+ is = 9.461e-15	   n = 1.098		  rs = 3.5897e-1
+ibv = 1e-3		 nbv = 4.0		  bv = 4.3
+ikf = 2.904e-1
***** capacitance parameter *****
+cjo = 1.882e-10	   m = 8.110e-1		  vj = 2.597 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.020		 xti = 3
+trs1 = 6.285e-4	trs2 = 5.885e-6		tikf = 5e-3
+tbv1 = 5.676e-5	tbv2 = 8.026e-7
.ends BZX584C3
*$
